Lista de Exercícios - Estrutuas : Enquanto, Para e Repita

 

* Faça um algoritmo que imprima todos os números inteiros de 1 a N, onde N é um  número fornecido pelo usuário.

algoritmo "Todos numeros inteiros de 1 a N"

var
   N, num:inteiro

 
inicio
   num <- 1

   escreval("Informe um número: ")
   leia(N)
   enquanto (num <= N) faca
      escreval(num, " * ")
      num <- num + 1
   fimenquanto

fimalgoritmo

* Faça um algoritmo que receba um número N, some todos os números inteiros de 1 a N, e mostre o resultado obtido.

algoritmo "Soma do inteiros de 1 a N"

var
   I, N, total:inteiro
  
inicio

   escreval("Informe um numero: ")
   leia(N)

     para I de 1 ate N faca
         total <- total + I
     fimpara
     escreva ("A Soma dos números é ", total)

fimalgoritmo

* Elabore um algoritmo que imprima todos os múltiplos de 4 compreendidos entre 5 e 87.

algoritmo "Numeros Multiplos de 4"

var
   I:inteiro
  
inicio

     I <- 5
    
     Repita

      se ( I mod 4 = 0) entao
          escreval (I, " é multiplo de 4")
      fimse
     
      I <- I + 1

     ate I = 87
    
fimalgoritmo

* Escreva um algoritmo que imprima todos os múltiplos de um número N fornecido pelo usuário, compreendidos entre dois números A e B também fornecidos pelo usuário.

algoritmo "Numeros Multiplos de um numero"

var
   N, A, B, I:inteiro
  
inicio

   escreval ("Digite um numero: ")
   leia (N)
   escreval ("Informe um numero inicial e um final para um intervalo: ")
   leia (A, B)

   I <- A

   enquanto (I <= B) faca

      se (I mod N = 0) entao
          escreval(I," É Multiplo de ",N)
      fimse

      I <- I + 1
     
   fimenquanto
  
fimalgoritmo

* Imprima uma tabela de conversão de polegadas para centímetros, de 1 a 20. Considere que Polegada = Centímetro * 2,54.

algoritmo "Conversão de polegadas para centímetros"

var
    I:inteiro
  
inicio

    escreval("|---------------------------------------|")
    escreval("|------------ T A B E L A --------------|")
    escreval("|CONVERSÃO DE POLEGADAS PARA CENTIMETROS|")
    escreval("|---------------------------------------|")

    para I de 1 ate 20 faca

      escreval("|---------------------------------------|")
      escreval("|-----",I," polega(S) é igual a ", I * 2.45 ," cm ")
      escreval("|_______________________________________|")

    fimpara
   
fimalgoritmo

* Dado dois números, o inicial e o final, calcule a soma de todos os números pares contidos nesse intervalo.

algoritmo "A soma dos numeros pares"

var
   total, I, N1, N2:inteiro

inicio

   escreval ("Informe dois valores inicial e final: ")
   leia(N1, N2)
  
   I <- N1
  
   Repita

     se (I mod 2 = 0) entao
        total <- total + I
     fimse

   I <- I + 1

   ate I > N2
   escreva ("A Soma dos números par é igual a ", total)

fimalgoritmo

* A série de Fibonacci é formada pela seguinte seqüência: 1, 1, 2, 3, 5, 8, 13, 21, 34, ... etc. Nesta série, o próximo elemento é obtido através soma dos dois anteriores. Escreva um algoritmo que exiba a série de Fibonacci até o vigésimo termo.

algoritmo "A série de Fibonacci "

var
   I, fibo, t1, t2:inteiro
  
inicio

   fibo <- 1
   t1 <- 1
   t2 <- 1

   para I de 1 ate 20 faca

      se (I <= 2 ) entao
          fibo <- 1
      senao
          fibo <- t1+t2
          t1 <- t2
          t2 <- fibo
      fimse
      escreval("Termo ", I, " é igual ", fibo)

   fimpara
  
fimalgoritmo

* Faça um algoritmo que calcule o fatorial de um número N fornecido pelo usuário.

algoritmo "Fatorial de um número N"

var
   I, N, fat:inteiro
  
inicio

   escreval("Entre com um numero :")
   leia(N)

      I <- 1
      fat <- 1
     
      Repita

       fat <- fat * I
       I <- I + 1

      ate I > N

      escreva("O Fatorial de", N, " é ", fat)

fimalgoritmo